Microsoft Office Excel
uređuje Dragan Grbić

O aktivnim ćelijama na radnim listovima

Nivo:
NIVO 3 - Prilozi na ovom nivou su namenjeni naprednim korisnicima, onima koji se već dobro snalaze u programima i onima koji već imaju iskustva u naprednim tehnikama. Ovom nivou pripadaju preporuke i trikovi koje bi trebalo da savlada svako ko teži dugotrajnom i efikasnom radu u Office programima.

Postoje različite tehnike kontrole aktivne ćelije radnog lista. Najpre se upoznajte sa elementarnim tehnikama kontrole iz VBA, a potom pogledajte i jedan zanimljiv primer sinhronizacije aktivnih ćelija cele radne sveske.

Ako intenzivno radite sa više radnih listova, verovatno znate za tehnike "zbirnog" rada u njima. Na primer, ako označite više radnih listova odjednom (koristeći SHIFT ili CTRL dok birate njihove jezičke), ulazite u režim grupnog editovanja. Na primer, kada uneste neki sadržaj na aktivni radni list ili mu promenite neki atribut izgleda, ćelije sa istim adresama će primiti isti sadržaj ili izgled.

Primetili ste da svaki radni list pamti poslednju aktivnu ćeliju. U nekim slučajevima, to može biti zbunjujuće za neke manje iskusne korisnike, mada prosta navigacija sa tastature rešava pitanje: CTRL+HOME aktivira ćeliju A1, odnosno gornju levu nezamrznutu ćeliju ako ste upotrebili alatku Freeze Panes; CTRL+END vas postavlja na donji desni ugao upotrebljenog dela radnog lista.

Ako želite da na neki način automatizujete aktiviranje željene ćelije radnog lista, to ćete učiniti uz pomoć jednostavnih VBA procedura događaja. Evo šta da učinite: otvorite VBE (ALT+F11), pa u oknu Project u grupi Microsoft Excel Objects radne sveske kliknite dvaput na ime željenog radnog lista. U desnom oknu modula radnog lista, u levoj listi na vrhu odaberite stavku Worksheet, a u desnoj događaj Activate; pojaviće se prazna procedura Worksheet_Activate u čije telo treba dodati samo jedan jedini red. Na kraju, to izgleda ovako:

Private Sub Worksheet_Activate()
   Range("C12").Select
End Sub

Prema ovom primeru, kada god aktivirate radni list koji ima ovu proceduru događaja, aktiviraće se ćelija C12 (odaberite sami ćeliju koja vam je potrebna). Možete biti i precizniji: ako imate neki radni list koji vam služi isključivo za popunu neke liste, možete defiisati da se aktivira ćelija prvog sledećeg praznog reda, u kom god redu ona bila. Hajde da iskomplikujemo scenario: na vrhu radnog lista imate neki naslov, pa prazan red, a zaglavlje liste počinje tek u ćeliji A3. Evo prikladne procedure događaja za ovaj radni list:

Private Sub Worksheet_Activate()
   Range("A3").Select
   Selection.End(xlDown).Offset(1, 0).Select
End Sub

Najzad, evo jedne male stilske vežbe u VBA iz koje možete naučiti neke interesantne tehnike.

Pretpostavimo se radna sveska sastoji iz serije radnih listova zasnovanih na istom obliku tabele; unapred ih je nepoznat broj. Želite da pregledate jedan po jedan radni list, ali tako da ćete možda menjati neki sadržaj koji se nalazi "ko zna gde" u tabeli. Bilo bi zanimljivo da sinhronizujete sve aktivne ćelije tih tabela tako da se adresom podudare sa trenutno aktivnom ćelijom na aktivnom radnom listu, zar ne? Nema standardnog alata za ovaj posao, pa ćemo napraviti svoj. Sledeći makro ubacite u standardni modul radne sveske (Insert/Module u meniju VBE) i njegovim aktiviranjem ćete sinhronizovati aktivne ćelije radnih listova; kao polazište, možete označiti i blok ćelija radnog lista, koji čak ne mora biti kontinualan.

' sinhronizacija aktivne ćelije ili bloka
' na svim radnim listovima radne sveske

Sub SinhroBlok()


' ako je aktivni list druge prirode,
' npr. list grafikona, prekini proceduru

If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub

' inicijalizacija promenljivih

Dim PolazniList As Worksheet, list As Worksheet
Dim GornjiRed As Long, LevaKolona As Integer
Dim Selekcija As String

' sprečavamo bljeskanje slike na ekranu

Application.ScreenUpdating = False

' pamti se polazni list

Set PolazniList = ActiveSheet

' hvatamo informacije o položaju pregleda
' i adresi označene ćelije ili selekcije

GornjiRed = ActiveWindow.ScrollRow
LevaKolona = ActiveWindow.ScrollColumn
Selekcija = ActiveWindow.RangeSelection.Address

' petlja prolazi kroz sve radne listove

For Each list In ActiveWorkbook.Worksheets

   ' pitalica preskače skrivene listove
   ' (Hidden Sheets)

   If list.Visible Then
      list.Activate
      Range(Selekcija).Select
      ActiveWindow.ScrollRow = GornjiRed
      ActiveWindow.ScrollColumn = LevaKolona
   End If
Next list

' vraćamo se na polzano mesto
' i osvežavamo sliku na ekranu

PolazniList.Activate
Application.ScreenUpdating = True

End Sub

NAPOMENA:
Ako vam se ovaj makro učini prikladnim, sačuvajte ga u biblioteci makroa (Personal Macro Workbook). Pročitajte prilog o tehnikama upotrebe ove namenske radne sveske.